@echo off
SetLocal EnableDelayedExpansion
rem Определяем переменные
SET CONF=ftp.cnf
SET FILELIST=f.txt
SET HOST=ftp.host.lan
SET USERNAME=ftpuser
SET PASSWORD=PaS$w0Rd
rem Создаем файл конфигурации для автоматизации работы ftp-клиента
rem в котором сканируем файлы по маске с учетом регистра
echo.open %HOST%> %CONF%
echo.%USERNAME%>> %CONF%
echo.%PASSWORD%>> %CONF%
echo.binary>> %CONF%
echo.ls *_IN.zip>> %CONF%
echo.ls *_IN.ZIP>> %CONF%
echo.ls *_in.zip>> %CONF%
echo.ls *_in.ZIP>> %CONF%
echo.bye>> %CONF%
rem Запускаем ftp-клиент в автоматическом режиме,
rem выводим результаты просмотра каталога в текстовый файл,
rem фильтруя выводимые имена файлов
ftp -s:%CONF% | findstr /i "[a-z,_,0-9]_IN.zip" > %FILELIST%
rem Вторично создаем файл конфигурации
echo.open %HOST%> %CONF%
echo.%USERNAME%>> %CONF%
echo.%PASSWORD%>> %CONF%
echo.binary>>%CONF%
rem Записываем в конфигурацию удаление всех найденных
rem файлов, с обрезанием Chr(13) в конце строки
for /f %%a in (%FILELIST%) do (
SET SYMBOL=%%a
echo del !SYMBOL:~0,-1!
)>> %CONF%
echo.bye>>%CONF%
rem Включаем эхо для контроля и запускаем ftp-клиент
echo on
ftp -s:%CONF%
@echo off
del %FILELIST%
del %CONF%
pause
Постоянно забываю как убрать принудительное текстовое форматирование в таблицах OpenOffice, поэтому просто копирую эту статью из базы знаний: Символ «'» (апостроф) Если перед числами в строке ввода стоит символ «'», то в этом случае цифры не распознаются как числа. Символ «'» (апостроф) является символом принудительного форматирования данных «как текст», поэтому он не отображается в ячейках; увидеть его можно только в строке ввода перед данными. «Язык формул» электронных таблиц разработан задолго до появления MS Windows и Microsoft Office. Символ «апостроф» в начале содержимого ячейки всегда был символом принудительного форматирования содержимого «как текст». Данный способ форматирования является преимущественным перед форматом ячейки. Так работали Quatro Pro, Super Calc, таблицы Lotus 1-2-3. Так работают и все современные электронные таблицы. «'» перед цифровыми значениями следует использовать, когда вводятся константы, не являющиеся числами. Например ...
Комментарии